windows 10 cd-key 확인 3가지 방법

바로 전 CD-KEY 보기 부분에서 실수를 많이 하는 바람에 이번에는 CD-KEY를 볼 수 잇는 몇몇 가지 방법을 적어 보려고 합니다.

1. VBScript 이용 방법

VB Script를 이용하여 윈도우 제품키 정보 확인

PC의 바탕화면에 마우스 오른쪽을 누르고 새로 만들기(W) > 텍스트 문서를 눌러 밑의 소스를 넣습니다.

Option Explicit  

Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
  Save ProductData  
End If



'Convert binary to chars
Function ConvertToKey(Key)
        Const KeyOffset = 52
        Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
        'Check if OS is Windows 8
        isWin8 = (Key(66) \ 6) And 1
        Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
        i = 24
        Maps = "BCDFGHJKMPQRTVWXY2346789"
        Do
                  Current= 0
           j = 14
           Do
              Current = Current* 256
              Current = Key(j + KeyOffset) + Current
              Key(j + KeyOffset) = (Current \ 24)
              Current=Current Mod 24
               j = j -1
           Loop While j >= 0
           i = i -1
           KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
           Last = Current
        Loop While i >= 0  
        
        If (isWin8 = 1) Then
           keypart1 = Mid(KeyOutput, 2, Last)
           insert = "N"
           KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
           If Last = 0 Then KeyOutput = insert & KeyOutput
        End If        
        

        ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
   
        
End Function
'Save data to a file
Function Save(Data)
        Dim fso, fName, txt,objshell,UserName
        Set objshell = CreateObject("wscript.shell")
        'Get current user name  
        UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
        'Create a text file on desktop  
        fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
        Set fso = CreateObject("Scripting.FileSystemObject")
        Set txt = fso.CreateTextFile(fName)
        txt.Writeline Data
        txt.Close
End Function

위의 소스를 넣고 저장을 눌러 저장합니다. 보기 좋게 Windows 10 product key view.vbs으로 만들어 보겠습니다.

Windows 10 product key view.vbs.vbs

레지스트리이용 보기

regedit를 윈도우 실행 부분에 적으시고 밑의 부분까지 갑니다.

\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SoftwareProtectionPlatform

위의 위치에 가시면 BackupProductKeyDefault 값이 있습니다. 이 데이터가 CD_KEY입니다.

Key Finder 프로그램으로 확인하기

이곳 사이트에 가서 스크롤을 조금 내리시면 다운로드와 포터블의 버튼이 있습니다. 설치를 하시려면 다운로드하여 설치를 진행하시고 그냥 사용하시려면 포터블을 눌러 사용하시면 됩니다. 저는 설치하고 삭제하기가 귀찮아 포터블을 이용했습니다.

https://www.sterjosoft.com/key-finder.html (Mirror)

일단 기본적으로 다운로드는 차단됩니다. 복구를 눌러 다운로드합니다.

다운로드가 완료되면 압축을 풀어 폴더에 들어갑니다.

네모로 되어 있는 keyFinder.exe를 눌러 실행하고 잠시 기다리면 새 창이 열리면서 보여집니다.

이 프로그램은 그냥 설치되어 있는 cd-key를 다 보이더군요.

참고. "부팅 불가능한 윈도우즈에서 제품 키를 복구하는 방법"이라는 프로그램도 위 사이트 안에 있네요. 굳이 여기서 할 필요는 없는 것 같습니다.